# Amethyst - An experimental Minecraft server written in Elixir.
# Copyright (C) 2024 KodiCraft
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as
# published by the Free Software Foundation, either version 3 of the
# License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.

defmodule Amethyst.Server.Handshake do
  @moduledoc """
  This module contains the logic for the Handshake stage of the server.
  """
  require Logger
  use Amethyst.Server

  alias Amethyst.Minecraft.Read

  @impl true
  def init(state) do
    state
  end

  ## DESERIALIZATION
  @impl true
  # Handshake https://wiki.vg/Protocol#Handshake
  @spec deserialize(0, binary()) ::
          {:handshake, any(), any(), any(), :login | :status | :transfer}
  def deserialize(0x00, <<data::binary>>) do
    {[ver, addr, port, next], ""} = Read.start(data) |> Read.varint() |> Read.string() |> Read.ushort() |> Read.varint() |> Read.stop()
    next = case next do
      1 -> :status
      2 -> :login
      3 -> :transfer
      _ -> raise RuntimeError, "Client requested moving to an unknown state!"
    end
    {:handshake, ver, addr, port, next}
  end
  def deserialize(type, _) do
    raise RuntimeError, "Got unknown packet type #{type}!"
  end

  ## SERIALIZATION
  @impl true
  def serialize(_) do
    raise RuntimeError, "No packets can be transmitted while still in the handshake stage!"
  end

  ## HANDLING
  @impl true
  # Handshake https://wiki.vg/Protocol#Handshake
  @spec handle(any(), any(), any()) :: no_return()
  def handle({:handshake, 767, addr, port, next}, client, state) do
    Logger.info("Got handshake, version 767 on #{addr}:#{port}. Wants to move to #{next}")
    case next do
      :status -> Amethyst.Server.Status.serve(client, state)
      :login -> Amethyst.Server.Login.serve(client, state)
      _ -> raise RuntimeError, "Unhandled move to next mode #{next}"
    end
  end
  def handle(tuple, _, state) do
    Logger.error("Unhandled but known packet #{elem(tuple, 0)}")
    {:unhandled, state}
  end
end